Welcome Guest, please sign in to participate in a discussion. | Search | Active Topics | |
Registered User Joined: 10/7/2004 Posts: 28
|
Hi Bruce,
Is it possible to program Stockfinder to indentify stocks that on an intraday basis have not retraced more than a specified retracement level from their intraday low/high? For example if I want to indentify which stocks open and travel up from their open and have not retraced more than 38.2% (or 50%) from their intraday low can this be done? Even better yet is there a way to draw a line that represents the 38.2% or 50% area? Any hints or suggestions are appreciated. Thanks.
Don
|
|
Worden Trainer
Joined: 10/7/2004 Posts: 65,138
|
Do you just want lines posted at 38.2%, 50% and 61.8% of the way between the high and low of the day or are you interested in the open of the day playing into where the lines are being posted in some fashion?
-Bruce Personal Criteria Formulas TC2000 Support Articles
|
|
Registered User Joined: 10/7/2004 Posts: 28
|
Bruce, I would use the open to determine my long or short bias. If the current price is above the open I want to filter (for longs) for stocks that have not retraced (pulled back) more than 31.8% ( I may use 50% or 61.8% later) of their intraday range and just the opposite (for shorts). If the current price is below the opening price and the stock has not retraced (bounced) more than 38.2%. As I mentioned earlier, having a visual line(s) drawn would be great.
|
|
Worden Trainer
Joined: 10/7/2004 Posts: 65,138
|
I think the following RealCode Condition should return true the stock has not retraced the given percent from the extreme for the day when on the desired side of the open:
'|*****************************************************************|
'|*** StockFinder RealCode Condition - Version 5.0 www.worden.com
'|*** Copy and paste this header and code into StockFinder *********
'|*** Condition:Has Not Retraced
'|******************************************************************
'# FibLevel = UserInput.Single = 38.2
Static Level(1) As Single
Static DayOpen As Single
Static DayHigh(1) As Single
Static DayLow(1) As Single
If isFirstBar Then
Level(0) = FibLevel / 100
Level(1) = 1 - Level(0)
DayOpen = Single.NaN
DayHigh(1) = Single.NaN
DayLow(1) = Single.NaN
DayHigh(0) = Single.NaN
DayLow(0) = Single.NaN
Else If Price.DateValue.DayOfYear <> Price.DateValue(1).DayOfYear Then
DayOpen = Price.Open
DayHigh(1) = DayHigh(0)
DayLow(1) = DayLow(0)
DayHigh(0) = Price.High
DayLow(0) = Price.Low
Else
DayHigh(0) = System.Math.Max(DayHigh(0), Price.High)
DayLow(0) = System.Math.Min(DayLow(0), Price.Low)
End If
If Single.IsNaN(DayHigh(0)) Then
SetIndexInvalid
Else If (Price.Last > DayOpen AndAlso _
Price.Last > Level(1) * DayHigh(0) + Level(0) * DayLow(0)) OrElse _
(Price.Last < DayOpen AndAlso _
Price.Last < Level(0) * DayHigh(0) + Level(1) * DayLow(0)) Then
Pass
End If
You should be able to plot the desired line using the following RealCode Indicator (it plots price when the close equals the open):
'|******************************************************************
'|*** StockFinder RealCode Indicator - Version 5.0 www.worden.com
'|*** Copy and paste this header and code into StockFinder *********
'|*** Indicator:Intraday Fib Line
'|******************************************************************
'# FibLevel = UserInput.Single = 38.2
Static Level(1) As Single
Static DayOpen As Single
Static DayHigh(1) As Single
Static DayLow(1) As Single
If isFirstBar Then
Level(0) = FibLevel / 100
Level(1) = 1 - Level(0)
DayOpen = Single.NaN
DayHigh(1) = Single.NaN
DayLow(1) = Single.NaN
DayHigh(0) = Single.NaN
DayLow(0) = Single.NaN
Else If Price.DateValue.DayOfYear <> Price.DateValue(1).DayOfYear Then
DayOpen = Price.Open
DayHigh(1) = DayHigh(0)
DayLow(1) = DayLow(0)
DayHigh(0) = Price.High
DayLow(0) = Price.Low
Else
DayHigh(0) = System.Math.Max(DayHigh(0), Price.High)
DayLow(0) = System.Math.Min(DayLow(0), Price.Low)
End If
If Single.IsNaN(DayHigh(0)) Then
Plot = Single.NaN
Else If Price.Last > DayOpen Then
Plot = Level(1) * DayHigh(0) + Level(0) * DayLow(0)
Else If Price.Last < DayOpen Then
Plot = Level(0) * DayHigh(0) + Level(1) * DayLow(0)
Else
Plot = Price.Last
End If
-Bruce Personal Criteria Formulas TC2000 Support Articles
|
|
Registered User Joined: 1/7/2006 Posts: 6
|
Hi Bruce and thanks...in a similar fashion I use Hot Scans to trade the "Opening Range" 5 minute bars...is there a way stockfinder could filter for stocks that are trading within the opening range...and say "at opening range"...and continue this scan throughout the day....thanx
|
|
Worden Trainer
Joined: 10/7/2004 Posts: 65,138
|
The following RealCode Condition checks for the current price or close of the bar to be within the opening range:
'|*****************************************************************|
'|*** StockFinder RealCode Condition - Version 5.0 www.worden.com
'|*** Copy and paste this header and code into StockFinder *********
'|*** Condition:Close At Opening Range
'|******************************************************************
Static Top As Single
Static Bot As Single
If isFirstBar Then
Top = Single.NaN
Bot = Single.NaN
Else If Price.DateValue.DayOfYear <> Price.DateValue(1).DayOfYear Then
Top = Price.High
Bot = Price.Low
End If
If Single.IsNaN(Top) Then
SetIndexInvalid
Else
If Bot <= Price.Last AndAlso Price.Last <= Top Then
Pass
End If
End If
While the following RealCode Condition checks for any part of the price bar to be within the opening range:
'|*****************************************************************|
'|*** StockFinder RealCode Condition - Version 5.0 www.worden.com
'|*** Copy and paste this header and code into StockFinder *********
'|*** Condition:Bar At Opening Range
'|******************************************************************
Static Top As Single
Static Bot As Single
If isFirstBar Then
Top = Single.NaN
Bot = Single.NaN
Else If Price.DateValue.DayOfYear <> Price.DateValue(1).DayOfYear Then
Top = Price.High
Bot = Price.Low
End If
If Single.IsNaN(Top) Then
SetIndexInvalid
Else
If Bot <= Price.High AndAlso Price.Low <= Top Then
Pass
End If
End If
-Bruce Personal Criteria Formulas TC2000 Support Articles
|
|
Guest-1 |