Hi Bruce,

Gap Fill Daily

Please help with a formula for Gap Fill in StockFinder.  Gap is defined as Price distance from C(1) to Open.  The Gap can be either Up or Down.  Gap Fill must occur the next day, and must at a Minimun Completely fill the Gap, but price movement of the Fill may Continue past the C(1).  For Instance price of stock XYZ closes at $10.00 Yesterday.  This morning it Opens at $12.00, so there is an Up Gap of $2.00.  To fill the Gap today, XYZ must drop a Minimum of $2.00 back to $10.00, C(1) during today's trading, but price can drop Past the fill mark of $10.00 to $9.75 or less.

Can you help to design two (2) separate Real Code Conditions to verify Gap Fills, One for Up Gaps and One for Down Gaps? Input variables would be Gap Size in %, and Direction of Gap, Up or Down.  Would need to be for Intra-Day, and Daily time Frames.

Also, is there a way to determine the TIME of the Gap Fill? If I am in 1-hour Time Frame, will I know the Gap was filled during that Time Segment, say 11:00 am to 12:00 pm? It would be great to know the specifice Time that the Gap was Filled.

Thanks for your help.  I am open to questions or suggestions.

Ed

Maybe something like the following RealCode Condition? You can set the Percent setting to a positive value to check for gaps up and to a negative value to check for gaps down.

It will start returning true on the first bar where the gap was filled during the day, but there really isn't a way to make it return a time to use in a WatchList Column for example.

'|*****************************************************************|
'|*** StockFinder RealCode Condition - Version 5.0 www.worden.com 
'|*** Copy and paste this header and code into StockFinder *********
'|*** Condition:Filled Gap
'|******************************************************************
'# Percent = UserInput.Single = 1
Static Filled As Boolean
Static Gapped As Boolean
Static FirstDay As Boolean
Static PrevClose As Single
If isFirstBar Then
	Filled = False
	Gapped = False
	FirstDay = False
	PrevClose = Single.NaN
Else If Price.DateValue.DayOfYear <> Price.DateValue(1).DayOfYear Then
	Filled = False
	Gapped = False
	FirstDay = True
	PrevClose = Price.Last(1)
	If Percent > 0 Then
		If Price.Open >= (1 + Percent / 100) * PrevClose Then
			Gapped = True
		End If
	Else If Percent < 0 Then
		If Price.Open <= (1 + Percent / 100) * PrevClose Then
			Gapped = True
		End If
	End If
End If
If FirstDay = True Then
	If Gapped = True Then
		If Filled = True Then
			Pass
		Else If Percent > 0 Then
			If Price.Low <= PrevClose Then
				Filled = True
				Pass
			End If
		Else If Percent < 0 Then
			If Price.High >= PrevClose Then
				Filled = True
				Pass
			End If
		End If
	End If
Else
	SetIndexInvalid
End If

Hi Bruce,

Thanks or the condition formulas!!  They work great, both Daily and Intra-day.

Ed

You're welcome.