Inputs:
Price((H+L)/2);

Vars:
InPhase(0),
Quadrature(0),
Phase(0),
DeltaPhase(0),
count(0),
InstPeriod(0),
Period(0),
DCPhase(0),
RealPart(0),
ImagPart(0);

If CurrentBar > 5 then begin

{Compute InPhase and Quadrature components}
Value1 = Price - Price[6];
Value2 =Value1[3];
Value3 =.75*(Value1 - Value1[6]) + .25*(Value1[2] - Value1[4]);
InPhase = .33*Value2 + .67*InPhase[1];
Quadrature = .2*Value3 + .8*Quadrature[1];

{Use ArcTangent to compute the current phase}
If AbsValue(InPhase +InPhase[1]) > 0 then Phase =
ArcTangent(AbsValue((Quadrature+Quadrature[1]) / (InPhase+InPhase[1])));

{Resolve the ArcTangent ambiguity}
If InPhase < 0 and Quadrature > 0 then Phase = 180 - Phase;
If InPhase < 0 and Quadrature < 0 then Phase = 180 + Phase;
If InPhase > 0 and Quadrature < 0 then Phase = 360 - Phase;

{Compute a differential phase, resolve phase wraparound, and limit delta phase errors}
DeltaPhase = Phase[1] - Phase;
If Phase[1] < 90 and Phase > 270 then DeltaPhase = 360 + Phase[1] - Phase;
If DeltaPhase < 1 then DeltaPhase = 1;
If DeltaPhase > 60 then Deltaphase = 60;

{Sum DeltaPhases to reach 360 degrees. The sum is the instantaneous period.}
InstPeriod = 0;
Value4 = 0;
For count = 0 to 40 begin
Value4 = Value4 + DeltaPhase[count];
If Value4 > 360 and InstPeriod = 0 then begin
InstPeriod = count;
end;
end;

{Resolve Instantaneous Period errors and smooth}
If InstPeriod = 0 then InstPeriod = InstPeriod[1];
Value5 = .25*InstPeriod + .75*Value5[1];

{Compute Dominant Cycle Phase, Sine of the Phase Angle, and Leadsine}
Period = IntPortion(Value5);
RealPart = 0;
ImagPart = 0;
For count = 0 To Period - 1 begin
RealPart = RealPart + Sine(360 * count / Period) * (Price[count]);
ImagPart = ImagPart + Cosine(360 * count / Period) * (Price[count]);
end;
If AbsValue(ImagPart) > 0.001 then DCPhase = Arctangent(RealPart / ImagPart);
If AbsValue(ImagPart) <= 0.001 then DCPhase = 90 * Sign(RealPart);

DCPhase = DCPhase + 90;
If ImagPart < 0 then DCPhase = DCPhase + 180;
If DCPhase > 315 then DCPhase = DCPhase - 360;

Plot1(Sine(DCPhase), "Sine");
Plot2(Sine(DCPhase + 45), "LeadSine");

end;

===============================================================

Dont know if this helps, I think its a later version. (by Ehlers)
To my eye it seems simpler to calculate.

(Remarks are in red)


Thanks
diceman

Bruce,
I was able to create an indicator from your original code that I'm going to use as the dominant Cycle period (= smoothperiod).  It plots fine as a positive single or double number.

I want to use it to control the iterations of another realcode indicator (via drag and drop ) with an adjustment thru a positive userinput variable (e.g. .5).   Since the smoothperiod is not an integer and even if it was, the adjustment value could generate a value that is not an integer - I need to round it and create an integer.  I was following a format used in your first code example -
 
         Dim DCPeriod As Integer = System.Math.Floor(SmoothPeriod(0) + .5)

- keep getting compile error(s)

This is what I have which I thought was fairly straightforward

'# Cumulative
'# AdjValue = UserInput.single = .5
'# SP = chart.EhlersSmoothPeriod

Dim SP2 As Integer = System.Math.Floor(SP + .5)   ' error on this line

    For count = 0 To SP2
  
              ' RSI logic
   
     Next
 
' plot rsi 

I've tried a number of different things and that line is still a problem

The error message I get is  -  Operator '*' is not defined for types "wbi.commonblocks.scriptingLine" and double

When I add the userinput multiplier within the parens, the message becomes   -  Operator is not defined for types single and wbi.commonblocks.scriptingLine

I'd appreciate some more help here - with the loop.   I believe I can get the rsi portion.

Thanks
BobMc